Предыдущая | Следующая | Оглавление

getURL()

Доступность

Flash 2. Опции GET и POST доступны только в Flash Player 4 и более новых версиях.

Синтаксис

getURL(url:String [, window:String [, "variables":String]]) : Void

Параметры

url Адрес (URL) доставляемого документа.

window Необязательный параметр, указывающий окно или фрейм HTML, в который должен быть загружен документ. Вы можете ввести имя специально названного окна или выбрать из следующих зарезервированных имен:

• _self указывает на текущий фрейм в текущем окне.
• _blank указывает на новое окно.
• _parent указывает на фрейм-родитель по отношению к текущему фрейму.
• _top указывает на фрейм самого верхнего уровня в текущем окне.

variables Метод GET или POST для отправляемых переменных. Если переменных нет, то параметр можно не использовать. Метод GET присоединяет переменные к концу URL, этот метод используется при малом числе переменных. Метод POST отправляет переменные в отдельном заголовке HTTP и используется для отправки многострочных переменных.

Возвращает

Ничего.

Описание

Функция; загружает документ с указанного адреса URL в окно, либо передает переменные другому приложению по указанному адресу URL. Для проверки этой функции убедитесь, что загружаемый файл имеется по указанному адресу. Для использования абсолютного адреса URL (например, http://www.myserver.com), вам необходимо сетевое подключение.

Пример

Этот пример загружает в мувиклип изображение. Когда по изображению выполнен щелчек мышью, то новый адрес URL будет загружен в новом окне браузера.

var listenerObject:Object = new Object();
listenerObject.onLoadInit = function(target_mc:MovieClip) {
  target_mc.onRelease = function() {
    getURL("http://www.macromedia.com/software/flash/flashpro/", "_blank");
  };
};
var logo:MovieClipLoader = new MovieClipLoader();
logo.addListener(listenerObject);
logo.loadClip("http://www.macromedia.com/images/shared/product_boxes/159x120/159x120_box_flashpro.jpg", this.createEmptyMovieClip("macromedia_mc", this.getNextHighestDepth()));

В следующем примере getURL() использована для отправки сообщения электронной почтой:

myBtn_btn.onRelease = function(){
  getURL("mailto:you@somedomain.com");
};

В следующем ActionScript использован JavaScript для открытия окна с предупредительным сообщением, при условии, что файл SWF встроен в окно браузера:

myBtn_btn.onRelease = function(){
  getURL("javascript:alert('вы нажали на меня')");
};

Также, вы можете использовать GET или POST для отправки переменных. Следующий пример использует GET для присоединения переменных к URL:

var firstName:String = "Гус";
var lastName:String = "Ричардсон";
var age:Number = 92;
myBtn_btn.onRelease = function() {
  getURL("http://www.macromedia.com", "_blank", "GET");
};

Следующий ActionScript использует POST для отправки переменных в заголовке HTTP. Удостоверьтесь, что проверяете ваш документ в окне браузера, потому что в противном случае ваши переменные будут отправлены с использованием метода GET:

var firstName:String = "Гус";
var lastName:String = "Ричардсон";
var age:Number = 92;
getURL("http://www.macromedia.com", "_blank", "POST");

См. также

loadVariables(), XML.send(), XML.sendAndLoad(), XMLSocket.send()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление